Cách tạo ESP8266 Web Server

Bài viết này sẽ hướng dẫn bạn từng bước xây dựng một web server chạy trên một con chip ESP8266 để điều khiển hai đầu ra (hai LED). ESP8266 NodeMCU Web Server này tương thích với các thiết di động và nó có thể được truy cập từ bất cứ một thiết bị nào sử dụng browser trong mạng local nhà bạn.

Nếu bạn muốn tìm hiểu kĩ hơn về mô đun ESP8266, thì đầu tiên hãy đọc bài viết này của mình Giới thiệu về ESP8266 Sơ đồ chân ESP8266.

Chuẩn bị Arduino IDE

  1. Tải và cài đặt Arduino IDE trên hệ điều hành của bạn
  2. Sau đó, bạn cần cái đặt ESP8266 add-on cho Arduino IDE. Để làm được điều này, tới File > Preferences
  3. Nhập vào trường Additional Board Manager URLs như được miêu tả trong hình dưới. Sau đó, click OK
  4. Đi tới Tools > Board > Boards Manager

  5. Cuộn xuống, lựa chọn bo ESP8266 và cài đặt esp8266 by ESP8266 Community như miêu tả trong hình vẽ dưới
  6. Đi tới Tools > Board và chọn bo ESP8266 của bạn. Sau đó, mở lại Arduino IDE của bạn.

Code

Copy đoạn code sau tới Arduino IDE của bạn, tuy nhiên đừng upload vội. Bạn cần thay đổi đôi chút để làm nó chạy đúng.

// Load Wi-Fi library
#include <ESP8266WiFi.h>

// Replace with your network credentials
const char* ssid     = "REPLACE_WITH_YOUR_SSID";
const char* password = "REPLACE_WITH_YOUR_PASSWORD";

// Set web server port number to 80
WiFiServer server(80);

// Variable to store the HTTP request
String header;

// Auxiliar variables to store the current output state
String output5State = "off";
String output4State = "off";

// Assign output variables to GPIO pins
const int output5 = 5;
const int output4 = 4;

// Current time
unsigned long currentTime = millis();
// Previous time
unsigned long previousTime = 0; 
// Define timeout time in milliseconds (example: 2000ms = 2s)
const long timeoutTime = 2000;

void setup() {
  Serial.begin(115200);
  // Initialize the output variables as outputs
  pinMode(output5, OUTPUT);
  pinMode(output4, OUTPUT);
  // Set outputs to LOW
  digitalWrite(output5, LOW);
  digitalWrite(output4, LOW);

  // Connect to Wi-Fi network with SSID and password
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  // Print local IP address and start web server
  Serial.println("");
  Serial.println("WiFi connected.");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  server.begin();
}

void loop(){
  WiFiClient client = server.available();   // Listen for incoming clients

  if (client) {                             // If a new client connects,
    Serial.println("New Client.");          // print a message out in the serial port
    String currentLine = "";                // make a String to hold incoming data from the client
    currentTime = millis();
    previousTime = currentTime;
    while (client.connected() && currentTime - previousTime <= timeoutTime) { // loop while the client's connected
      currentTime = millis();         
      if (client.available()) {             // if there's bytes to read from the client,
        char c = client.read();             // read a byte, then
        Serial.write(c);                    // print it out the serial monitor
        header += c;
        if (c == '\n') {                    // if the byte is a newline character
          // if the current line is blank, you got two newline characters in a row.
          // that's the end of the client HTTP request, so send a response:
          if (currentLine.length() == 0) {
            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
            // and a content-type so the client knows what's coming, then a blank line:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println("Connection: close");
            client.println();
            
            // turns the GPIOs on and off
            if (header.indexOf("GET /5/on") >= 0) {
              Serial.println("GPIO 5 on");
              output5State = "on";
              digitalWrite(output5, HIGH);
            } else if (header.indexOf("GET /5/off") >= 0) {
              Serial.println("GPIO 5 off");
              output5State = "off";
              digitalWrite(output5, LOW);
            } else if (header.indexOf("GET /4/on") >= 0) {
              Serial.println("GPIO 4 on");
              output4State = "on";
              digitalWrite(output4, HIGH);
            } else if (header.indexOf("GET /4/off") >= 0) {
              Serial.println("GPIO 4 off");
              output4State = "off";
              digitalWrite(output4, LOW);
            }
            
            // Display the HTML web page
            client.println("<!DOCTYPE html><html>");
            client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
            client.println("<link rel=\"icon\" href=\"data:,\">");
            // CSS to style the on/off buttons 
            // Feel free to change the background-color and font-size attributes to fit your preferences
            client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
            client.println(".button { background-color: #195B6A; border: none; color: white; padding: 16px 40px;");
            client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
            client.println(".button2 {background-color: #77878A;}</style></head>");
            
            // Web Page Heading
            client.println("<body><h1>ESP8266 Web Server</h1>");
            
            // Display current state, and ON/OFF buttons for GPIO 5  
            client.println("<p>GPIO 5 - State " + output5State + "</p>");
            // If the output5State is off, it displays the ON button       
            if (output5State=="off") {
              client.println("<p><a href=\"/5/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/5/off\"><button class=\"button button2\">OFF</button></a></p>");
            } 
               
            // Display current state, and ON/OFF buttons for GPIO 4  
            client.println("<p>GPIO 4 - State " + output4State + "</p>");
            // If the output4State is off, it displays the ON button       
            if (output4State=="off") {
              client.println("<p><a href=\"/4/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/4/off\"><button class=\"button button2\">OFF</button></a></p>");
            }
            client.println("</body></html>");
            
            // The HTTP response ends with another blank line
            client.println();
            // Break out of the while loop
            break;
          } else { // if you got a newline, then clear currentLine
            currentLine = "";
          }
        } else if (c != '\r') {  // if you got anything else but a carriage return character,
          currentLine += c;      // add it to the end of the currentLine
        }
      }
    }
    // Clear the header variable
    header = "";
    // Close the connection
    client.stop();
    Serial.println("Client disconnected.");
    Serial.println("");
  }
}

Bạn cần thay đổi 2 biến sau phụ thuộc vào mạng wifi nhà bạn. ESP8266 sau đó mới có thể kết nối tới router của bạn được.

// Replace with your network credentials
const char* ssid = "";
const char* password = "";

Nạp Arduino code (Sketch)

Nạp code cho ESP-12E

Nếu bạn đang sử dụng một bo ESP-12E NodeMCU, việc nạp code sẽ rất dễ dàng vì bộ nạp đã được tích hợp trên bo. Cắm bo của bạn vào máy tính qua dây USB. Đảm bảo rằng bạn đã lựa chọn đúng loại bo và cổng COM kết nối đến nó.

Sau đó click nút Upload trên Arduino IDE và chờ một vài dây cho đến khi thấy bản tin Done uploading ở góc dưới phía trái.

Nạp code cho ESP-01

Việc nạp code cho ESP-01 yêu cầu phải thiết lập một kết nối truyền thông nối tiếp (serial communication) giữa bo ESP8266 và bộ nạp code FTDI (FTDI programmer) như miêu tả trong sơ đồ nguyên lý bên dưới.

Bảng sau miêu tả các kết nối bạn cần thực hiện giữa ESP8266 và bộ nạp FTDI.

ESP8266FTDI programmer
RXTX
TXRX
CH_PD3.3V
GPIO 0GND
VCC3.3V
GNDGND

Nếu bạn dùng một bộ nạp FTDI mới, bạn có thể cần cài đặt FTDI driver trên máy tính Windows của bạn. Truy cập trang để tải.

Sau đó bạn chỉ cần kết nối bộ nạp tới máy tính và nạp code cho ESP8266.

Sơ đồ nguyên lý

Để xây dựng mạch phần cứng cho bài hướng dẫn này, bạn cần những thành phần sau:

Nếu bạn đang sử dụng ESP-01, bạn còn phải cần mua một bộ nạp FTDI hoặc Serial Adapter.

Kết nối hai LED tới bo ESP8266 MCU như được miêu tả trong sơ đồ nguyên lý sau – với một LED được kết nối tới chân GPIO4 (D2) và LED còn lại kết nối tới GPIO5 (D1).

Nếu bạn đang sử dụng ESP-01

Nếu bạn đang sử dụng ESP8266-01, hãy sử dụng sơ đồ nguyên lý sau để tham khảo, tuy nhiên bạn cần phải thay đổi các chân kết nối với LED (thành GPIO2 và OPIO0).

Test Web Server

Bây giờ bạn có thể nạp code, và nó sẽ chạy tức thì. Đừng quên kiểm tra nếu bạn đang sử dụng đúng bo ESP8266 và cổng COM kết nối với nó. Mở Serial Monitor với thiết lập baud rate là 115200.

Tìm địa chỉ IP của ESP8266

Nhấn nút RESET trên bo ESP8266, và nó sẽ in ra một địa chỉ IP trên Serial Monitor.

Copy địa chỉ IP này, bởi vì bạn cần nó để truy cập vào Web Server.

Truy cập vào Web Server

Mở web brower trên máy tính của bạn, đánh địa chỉ IP của ESP, và bạn sẽ thấy một trang web như sau. Trang web này được phản hồi bởi ESP8266 khi bạn gửi một bản tin request tới nó.

Nếu nhìn kĩ vào serial monitor, bạn có thể thấy quá trình xẩy ra đàng sau đó. ESP nhận bản tin yêu cầu từ một client mới – trong trường hợp này là browser của bạn.

Bạn có thể cũng thấy các thông tin khác về bản tin request này. Các trường này được gọi là trường HTTP header, và chúng định nghĩ các thông số hoạt động của một tiến trình HTTP.

Chạy thử Web Server

Hãy cũng nhau chạy thử web server. Click vào nút bấm để bật GPIO5 lên. ESP nhận một bản tin request dựa theo đường dẫn /5/on, và bật LED 5 sáng.

Trạng thái LED cũng được cập nhật trên giao diện web.

Kiểm tra bằng việc ấn nút GPIO4 và thấy rằng nó chạy tương tự như trên.

Code làm việc như thế nào

Các bạn có thể xem qua video để hiểu về cách làm việc của code

Bản quyền bài viết thuộc về NhaThongMinhPlus.com

1 bình luận cho “Cách tạo ESP8266 Web Server

Trả lời

Email của bạn sẽ không được hiển thị công khai. Các trường bắt buộc được đánh dấu *